Уважаемые специалисты по медбиостатистике, опять нужна ваша неоценимая помощь.
Не мог найти в Интернете чётких указаний расчёта Хи-квадрата пирсона в программе SPSS 17 версии.
Как всем известно, что достоверность различий качественных показателей, либо выраженных в абсолютных числах, либо в процентах (ну, например, доля от целого), необходимо считать только методами непараметрической статистики. Их нельзя считать методами параметрической статистики - например, критерием Стьюдента. Так как это в корне неверно.
Это все известно.
В монографии МЕДИЦИНСКАЯ ДИССЕРТАЦИЯ: РУКОВОДСТВО / АВТ.-СОСТ. С.А. ТРУЩЕЛЁВ; ПОД РЕД. АКАД. РАМН, ПРОФ. И.Н. ДЕНИСОВА. -3-е изд., ПЕРЕРАБ. И ДОП. - М.: ГЭОТАР-МЕДИА, 2009. - 416С.
Приведена таблица какими методами в статистике надо считать свои данные.
Привожу таблицу в прикреплённом файле под номером 1

Вопрос: как располагать данные в таблице вышеуказанной программы, чтобы получилась таблица сопряжённости -частоты наблюдаемые и ожидаемые. для подсчёта Хи-квадрата Пирсона. И вообще что за частоты?
например, есть два ряда значений качественных
Первый ряд - в первый день лечения - это наблюдаемые? Второй ряд - после лечения тоже качественные. Это ряд ожидаемых частот ли?
Нигде точно не могу найти ответ. никто не знает.

P.S. Что-то не прикрепляется файл в Опере

Чтобы понять что такое наблюдаемы и ожидаемые частоты почитайте Стентон Гланц, 5 глава, есть в сети бесплатно.

Вот это мне нравится - что такое наблюдаемые и ожидаемые частоты, не знаем, а насчет того, что параметрической статистикой пользоваться нельзя - утверждаем.
И не надо сравнивать яблоки с апельсинами - тест четырехпольных таблиц (обычно называемый хи2 - хотя хи2 - это распределение) используется для номинальных переменных, а t-тест - для ординальных. Утверждение выше что-то вроде "надо измерять холестерин методом Абеля -Кендала, а не тонометром, так как это в корне неверно". Не знаете - спросите, а не играйте в "знайку" - получается только хуже.
Теперь по существу. Для четырехпольной таблицы надо иметь два столбца данных. В одном - единицы и нули = есть/нет признака, во втором - единицы/нули = до/после лечения сделаны измерения. Т.Е.:
1 1
1 0
0 1
0 0
первый - признак есть после лечения
второй - признак есть до лечения
третий - признака нет после лечения
четвертый - признака нет до лечения
Возможно, что данные уже просуммированы, тогда обычно добавляется третий столбец с частотами - количеством пациентов, т.е.
1 1 20
было двадцать пациентов с признаком после лечения
Однако...
До/после лечения обычно на одних и тех же пациентах, поэтому использовать хи2, который предполагает независимость показателей до/после "в корне неверно". Необходимо пользоваться тестом Мак-Неймара, который учитывает коррелированность данных до/после.

Что касается SPSS надо в меню Анализ-Описательные статистики-Таблицы сопряженности выбрать две переменные (признак, лечение) и после нажатия кнопки статистика выбрать хи2
В случае суммарной таблицы переменные надо предварительно "взвесить"
В синтаксисе все это будет выглядеть так:
WEIGHT BY var3.
CROSSTABS /TABLES= var1 BY var2 /STATISTICS =CHISQ.
var3 - переменная с "весовыми коэффициентами, var1 и var2 коды наличия признака и когда производится оценка (до/после лечения).

без взвешивания, понятно, нужна только вторая строка. Названия меню брал из 18 версии, синтаксис будет работать во всех версиях.

Не знаете - спросите, а не играйте в "знайку" - получается только хуже.

Уважаемый ПЛАВ, я не играю в знайку. Вас, конечно, никто не переплюнет в знании статистики, и это не моя задача Вас переплёвывать. за Вами остаётся право все комментировать и высказывать свои едкие утверждения.
Задача моих сообщений на Вашем форуме БЫСТРО, КАЧЕСТВЕННО, ПОЛНО и ТОЧНО найти ответы на мои вопросы, без "почитай то, почитай это". Да, я понимаю, что Вы СПЕЦИАЛИСТ в статистике и хотели бы Вы, чтоб почитали люди и знали о чем спрашивать. Вы знаете хорошо статистику, а я знаю хорошо другое. Не надо сравнивать людей. Пускай стоматолог занимается стоматологией. а эпидемиолог - эпидемиологией. Я не обязан всё знать. Я Вас никогда не оскорблял. Не надо было тогда форум создавать, если Вам трудно объяснить человеку. может быть та инфа, которую я здесь получил и не пригодится больше. В той монографии, которую я выше привёл, профессор рекомендует ИМЕТЬ ПРИ СЕБЕ специалиста по медбиостатистике. Я уверен, что 99% "форумчан" ЕГО НЕ ИМЕЮТ. О чём Вы говорите? Иначе б на Вашем форуме делать будет нечего.
СПАСИБО ЗА ОТВЕТ

Уважаемый Docanton, вы все же приведите данные, тогда легче будет объяснить вам, что именно вы хотите посчитать. Наблюдаемые и ожидаемые частоты понять без чтения самых простых книжек будет очень трудно и никакой доктор вам в личной беседе этого не объяснит.
Из характера ваших данных будет понятно, нужен ли вам критерий сопряженности Пирсона (не связанные выборки) или критерий М-Н для связанных.
В SPSS не выдается значение критерия М-Н (или я не знаю как), а только его статистическую оценку, но его легко посчитать руками.
NPAR TEST
/MCNEMAR=VAR00001 WITH VAR00002 (PAIRED)
/MISSING ANALYSIS.
Или в меню Two related Samples Tests поставьте метку Mc-Nemar
При этом в первой переменной должны быть значения признака до лечения у каждого больного (1, 0), а во второй у тех же больных после лечения (1, 0). Значения у 24 больных:
Var1 Var2
1 0 0
2 0 0
3 1 0
4 1 0
5 1 0
6 0 0
7 0 0
8 1 1
9 1 1
10 1 1
11 1 0
12 0 0
13 0 0
14 0 0
15 1 0
16 1 0
17 1 0
18 0 0
19 0 0
20 1 1
21 1 1
22 1 1
23 1 0
24 0 0

То, как предложил плав, эти данные будут выглядеть так:
1 1 6
1 0 8
0 1 0
0 0 10
Но, что дальше, откуда по предложенному синтаксису получится М-Н.
Я чего то не поняла с SPSS?

В одном вы правы, docanton, тут каждый хочет найти ответы на свои вопросы, но кто то должен на них отвечать, так давайте уважать тех, кто этим занимается.

Я не совсем понял про значение критерия, нужно именно значение хи2 М-Н? Просто Ваш код нормально отрабатывает, если использовать тот же CROSSTABS:
CROSSTABS
/TABLES= var5 BY var6
/STATISTICS=MCNEMAR.

Правда, в таблице ничего не стоит в разделе значение критерия, но, поскольку таблица сопряженности формируется, рассчитать его не составит труда, если нужно именно значение критерия, а не р. Кстати, в crosstabs можно заказать и точное значение, а не только асимптотическое( /METHOD=EXACT TIMER(5) ) - тут с ограничением времени расчета в 5 минут.
Вроде бы это происходит потому, что при небольшом числе случаев (пар) SPSS автоматически переключается на точное определение критерия, а не использует хи2 аппроксимацию, соответственно при большем числе пар (более 25?) начнется расчет критерия. Правда, попытка заставить SPSS рассчитать критерий увеличением числа дискордантных пар закончилась ничем - не считает .
На всякий случай прикрепляю найденное макро для расчета критерия М-Н в том случае, если количество пар более 10:
* MACRO definition (it also computes a 96%CI -Newcombe's method- for the
difference in percentages, nice extra!) *.
DEFINE MYMCNEMAR(!POSITIONAL !TOKENS(1) /!POSITIONAL
!TOKENS(1)/!POSITIONAL !TOKENS(1)/!POSITIONAL !TOKENS(1)).
DATASET NAME Datos.
DATASET DECLARE Resultados1 WINDOW=HIDDEN.
DATASET DECLARE Resultados2 WINDOW=HIDDEN.
PRESERVE.
SET ERRORS=NONE RESULTS=NONE.
MATRIX.
COMPUTE nanb=!1 .
COMPUTE napb=!2 .
COMPUTE panb=!3 .
COMPUTE papb=!4 .
COMPUTE a=nanb.
COMPUTE b=napb.
COMPUTE c=panb.
COMPUTE d=papb.
COMPUTE perc={(c+d)/(a+b+c+d);(b+d)/(a+b+c+d)}.
COMPUTE chi2=((b-c)**2)&/(b+c).
COMPUTE chi2sig=1-CHICDF(chi2,1).
COMPUTE chi2cor=(ABS(b-c)-1)**2&/(b+c).
COMPUTE chi2sigc=1-CHICDF(chi2cor,1).
COMPUTE z = 1.959964.
COMPUTE zsq = 1.959964*1.959964.
COMPUTE x5=papb+panb.
COMPUTE x6=napb+nanb.
COMPUTE x7=papb+napb.
COMPUTE x8=panb+nanb.
COMPUTE x9=x7+x8.
COMPUTE x10=(panb-napb)/x9.
COMPUTE x11=2*x5+zsq.
COMPUTE x12=z&*(zsq+4*x5&*x6/x9)&**0.5.
COMPUTE x13=2*(x9+zsq).
COMPUTE x14=(x11+x12)/x13.
COMPUTE x15=(x11-x12)/x13.
COMPUTE x16=x5/x9-x15.
COMPUTE x17=x14-x5/x9.
COMPUTE x21=2*x7+zsq.
COMPUTE x22=z&*(zsq+4*x7&*x8/x9)&**0.5.
COMPUTE x24=(x21+x22)/x13.
COMPUTE x25=(x21-x22)/x13.
COMPUTE x26=x7/x9-x25.
COMPUTE x27=x24-x7/x9.
COMPUTE x29=x5&*x6&*x7&*x8.
COMPUTE x30=1.
DO IF x29 EQ 0.
- COMPUTE x30=0.
END IF.
COMPUTE x31=papb&*nanb-panb&*napb.
COMPUTE x32=0.
DO IF (x31 GT 0).
- COMPUTE x32=1.
END IF.
COMPUTE x33=x31-x9/2.
COMPUTE x35=0.
DO IF (x33 GT 0).
- COMPUTE x35=x33.
END IF.
COMPUTE x36=x32&*x35+(1-x32)&*x31.
COMPUTE x37=x30&*x36.
COMPUTE x38=x30&*x29&**0.5+(1-x30).
COMPUTE x39=x37/x38. /* phi hat.
COMPUTE x40=x16&*x16-2*x39&*x16&*x27+x27&*x27.
COMPUTE x41=x17&*x17-2*x39&*x17&*x26+x26&*x26.
COMPUTE x42=x10-SQRT(x40).
COMPUTE x43=x10+SQRT(x41).
COMPUTE vnames={'P1','P2','Puntual','Inferior','Superior'}.
SAVE {100*T(perc),100*x10,100*x42,100*x43} /OUTFILE=Resultados1
/NAMES=vnames.
COMPUTE vnames={'Chi2','Sig'}.
SAVE {chi2,chi2sig;chi2cor,chi2sigc} /OUTFILE=Resultados2 /NAMES=vnames.
END MATRIX.
RESTORE.
DATASET ACTIVATE Resultados1.
FORMAT P1 TO Superior (PCT4.2).
VAR LABEL P1 'Porc. A'/P2 'Porc. B'/ Puntual 'Diferencia'.
OMS /SELECT TABLES
/IF COMMANDS='Summarize' SUBTYPES='Case Processing Summary'
/DESTINATION VIEWER=NO.
SUMMARIZE
/TABLES=ALL
/FORMAT=LIST NOCASENUM NOTOTAL
/TITLE='95%CI for difference in proportions (paired) (*)'
/CELLS=NONE.
OMSEND.
ECHO '(*) Exact (Newcombe method)'.
DATASET ACTIVATE Resultados2.
DATASET CLOSE Resultados1.
FORMAT chi2(F8.3) Sig (F8.4).
VAR LABEL chi2 'Chi?'/ Sig 'Sig.'.
STRING Test (A12).
IF ($casenum EQ 1) Test = 'Uncorrected' .
IF ($casenum EQ 2) Test = 'Corrected' .
OMS /SELECT TABLES
/IF COMMANDS='Summarize' SUBTYPES='Case Processing Summary'
/DESTINATION VIEWER=NO.
SUMMARIZE
/TABLES=Test chi2 Sig
/FORMAT=LIST NOCASENUM NOTOTAL
/TITLE='McNemar Chi-square statistics(*)'
/CELLS=NONE.
OMSEND.
DATASET ACTIVATE Datos.
DATASET CLOSE Resultados2.
ECHO '(*) Asymptotic'.
!ENDDEFINE.

вызов макро
MYMCNEMAR 10 12 4 20.

обсуждение тут :
http://old.nabble.com/No-chi-square-value-...td15462088.html

Этот макрос для SPSS потому и родился, что другие программы этот критерий считают, Statistica выдает значение критерия и в режиме таблиц и в режиме калькулятора при заполнении таблицы 2х2. Однако, интересует именно разность в-с, выраженная в процентах и ДИ к этой разнице, чего программы не делают, я в свое время слепила сама в Statistica, а этот макрос должен делать. Я поняла, что нужно для моего примера набрать MYMCNEMAR 10 0 8 6. Но куда нужно записать этот макрос, чтобы потом его вызвать? Создать скрипт вставив этот текст? Заранее спасибо.

Да, просто создаете новый файл скрипта, туда копирует макрос, вниз добавляете команду и все. Единственно, что макрос для большего числа дискордантных пар (более 10). Результат выглядит примерно так:
95%CI for difference in proportions (paired) (*)
Porc. A Porc. B Diferencia Inferior Superior
1 52,17% 69,57% -17,39% -32,93% -,37%

и
McNemar Chi-square statistics(*)
Test Chi? Sig.
1 Uncorrected 4,000 ,0455
2 Corrected 3,063 ,0801

Да я все так и делаю, но даже после исправления ошибки в тексте макроса (Chi?'), команда MYMCNEMAR у меня не распознается - неожиданный текст!
Результат для значения критерия также не подходит, для цифр 10 0 8 6 должно быть 6,125 для диагонали bc.

А я и не писал, что Ваш пример тестирую, я свой тестировал
Для вашего результаты вот какие:

95%CI for difference in proportions (paired) (*)
Porc. A Porc. B Diferencia Inferior Superior
1 58,33% 25,00% 33,33% 11,58% 50,37%

McNemar Chi-square statistics(*)
Test Chi? Sig.
1 Uncorrected 8,000 ,0047
2 Corrected 6,125 ,0133

На самом деле просто сейчас взял текст из поста, скопировал в новое окно синтаксиса, внес пустую строку и ввел команду MYMCNEMAR 10 0 8 6.
Точку после 6 не забываете?

Да, точку я ставлю, но как выяснилось, у меня не полная версия программы. Так что, придется обходится честно приобретенной Statistica. Спасибо!

часто слышу про неполную версию программы (обычно говорят про портативную), но выясняется, что просто не разбирались с ней. По идее макрос должен работать, поскольку реально дополнительных модулей (типа exact) не использует. Запостите что конкретно говорит SPSS после запуска макроса, может найдем причину? (при неполной версии должна жаловаться на отсутствие лицензии).

MYMCNEMAR 10 0 8 6.p{color:0;font-family:Monospaced;font-size:16pt;font-style:normal;font-weight:normal;text-decoration:none}
>Error # 1. Command name: MYMCNEMAR
>The first word in the line is not recognized as an SPSS command.
>This command not executed.

Возможно, вы правы и я что то не так делаю.

У меня два ряда значений. которые отражены в процентах. так ка это доли от целого.
Например,
Содержание сегментоядерных нейтрофилов в гное:

Первые сутки На четвёртые сутки
89% 77%
78% 76%
77% 60%
66% 67%
88% 70%

остальные клетки я в счёт не беру. Мне научный руководитель сказал, что мы там увидели продуктивные клетки и этого достаточно без подсчёта достоверности различий, что метод эффективен. Вот я хотел при помощи критерия Хи-квадрат подсчитать достоверность различий по этим двум столбикам. Или метод нужен здесь другой.
как добавлять в таблицу SPSS Скажите пожалуйста, СПЕЦИАЛИСТЫ

Похоже, что не прошел макрос, там какая-то ошибка - у Вас цветом синтаксис подсвечивается? Что там красное?

Красным, именно MYMCNEMAR.

Боюсь, что ответить так, как вы хотите у меня не получится. Все, что я поняла, это то, что проценты, это доли от целого.
А дальше, не понятно. Поэтому, вопрос первый, что вы представили в строках, у вас 5 больных? У первого больного в первый день содержание сегментоядерных нейтрофилов было 89% и это число выдает вам методика измерения, или есть какое то конкретное число, которое вы выразили в %, тогда это число нужно знать. Ваша научная гипотеза, очевидно, состоит в том, что на 4 день доля этих самых нейтрофилов снижается? Откуда возникла идея критерия Хи-квадрат? У вас есть хоть какие то частоты? Пусть хоть наблюдаемые.

На самом деле обычный хи2 тут не очень подходит. В реальности, чтобы проанализировать эти данные надо сделать многомерную таблицу (трехмерную), где строки - время, столбцы - тип клеток (сегметы/не сегменты) и третья размерность - объекты. Далее результаты суммируются, например с использованием критерия Мантеля-Ханзеля.
Проблема в том, что у Вас может не быть данных по общему количеству лейкоцитов в гное. В этом случае проблема большая, поскольку не имея знаменателя оценить влияние случайности нельзя.
Кроме того, если опираться только на данные, которые Вы привели, то никакого разговора об эффективности чего-либо вообще быть не может, поскольку причина изменения содержания % состава неизвестна, нет контрольной группы. Если же Вы привели только часть данных, а есть еще контрольная группа и группа вмешательства, то тогда вообще надо пользоваться пуассоновой регрессией или плюнуть на все, сделать арксинусную трансформацию процентов и спокойно пользоваться линейными моделями (проблема в том, что у Вас две цифры с одного объекта, значит они коррелированы, значит надо использовать анализ с повторными наблюдениями, а поскольку для разумной интерпретации результатов должны быть, как минимум, две группы, это дает смешанную модель. Смешанные модели даже в случае нормального распределения остатков не самые простые для понимания и использования, а уж если если отбросить допущение нормальности, то все будет совсем грустно).
Если данные вводятся так:
pct when idn
,89 ,0 1,00
,77 1,00 1,00
,78 ,0 2,00
,76 1,00 2,00
,77 ,0 3,00
,60 1,00 3,00
,66 ,0 4,00
,67 1,00 4,00
,88 ,0 5,00
,70 1,00 5,00
То в SPSS синтаксис будет выглядеть так
* арксинусная трансформация.
COMPUTE apct=ARSIN(SQRT(pct)).
EXECUTE.
* собственно модель.
MIXED apct BY when
/FIXED = when
/REPEATED = when | SUBJECT(idn) .

Кстати, по приведенным в посте данным различия не достоверны (р=0,104), что подтверждается и визуальной оценкой по критерию знаков - в одной группе из 5 есть повышение.

А макрос какого цвета?
И попробуйте сохраненный файл синтаксиса, который прикрепляю (архив по понятным причинам)

На сколько я понимаю, после запуска синтаксиса в окне output должен быть результат, а у меня и при запуске вашего варианта и после запуска с моими данными такая запись:
* MACRO definition (it also computes a 96%CI -Newcombe's method- for the
difference in percentages, nice extra!) *.
И все !

В AtteStat для данного примера так получилось.

Вот это вводим:
10 0
8 6

Вот это получаем:
Критерий Мак-Немара
Асимптотика хи-квадрат
Статистика, P-значение (двустороннее)
8,00 0,0047
Асимптотика с поправкой Йэйтса
Статистика, P-значение (двустороннее)
6,1250 0,0133
Точный условный
Статистика, P-значение (двустороннее)
8,0000 0,0039

Собственно, всё.

В том то и дело, что не все! Фишка в том, чтобы получить разность относительных частот (в-с) , выраженных в процентах и Ди к этой разнице. А синтаксис, предложенный плавом у меня не работает. Но у меня есть своя такая самоделка.

Тогда так:
10 0
8 6

Получаем:
Подготовка качественных данных
Таблица 2 x 2
10,00 0,00
8,00 6,00
Непараметрическая статистика и анализ качественных данных
Разность долей
0,43
Статистика, P-значение (двустороннее)
1,91 0,11
Доверительный интервал
Нижний 95% 0,08
Верхний 95% 0,77

Кстати, с недавних пор предлагаются к загрузке полные исходные коды AtteStat. В числе прочего в них входят исходники Справочной системы в формате RTF, с которыми можно обращаться как с обычными документами Word.

Получилась примерно такая картина:

Первые сутки содержание клеток (100%) - нейтрофилы сегментоядерные - 81,03 плюс минус 0,40%
нейтрофилы палочкоядерные - 2,03 плюс минус 0,78%
базофилы - 0,17 плюс минус 0,08
эозинофилы - 0,97 плюс минус 0,32
лимфоциты - 10,70 плюс минус 0,54
моноциты - 4,30 плюс минус 0,44
макрофаги - 0,67 плюс минус 0,24
плазмоциты - 0,13 плюс минус 0,08%

Четвёртые сутки содержания клеток в ране (100%) - нейтрофилы сегментоядерные - 80,53 плюс минус 0,74%
нейтрофилы палочкоядерные - 0,40 плюс минус 0,11%
базофилы - 0%
эозинофилы - 0,43 плюс минус 0,12
лимфоциты - 14,47 плюс минус 0,28
моноциты - 2,90 плюс минус 0,23
макрофаги - 0,90 плюс минус 0,16
плазмоциты - 0,37 плюс минус 0,05%

Вот примерно, по таким данным мне надо как-то сравнить, что по некоторым, возможно, клеткам есть достоверные различия. Какой метод лучше?


Нормы нет и не может быть, так как это индивидуальный процесс и в литературе таких данных тоже нет, чтобы принять их за норму.


Если кто-то из специалистов возьмётся объяснить суть решения в таблице SPSS, то прошу Вас объясните просто без применения тяжёлой математической интерпретации, сложных для понимания статистических терминов и тому подобное.

Не совсем так. До лечения голова болела у 14 больных (а всего было 24 больных), а после лечения у 6, т.е. у 8 исчез этот симптом. И к тому же голова не заболела ни у одного больного, у которого до лечения она не болела). Нужная для М-Н диагональ в-с=0-8. Т.е. интересует эта разница выраженная в процентах из общего числа больных, а не разница долей из таблицы сопряженности. А именно 8*100/24=33,3%. Или, до лечения голова болела у 14*100/24=58,3%, а после лечения у 6*100/24=25,0%. Разница и есть эффективность, т.о. те же 33,3%. К этим процентам и ДИ нужно.

Плав, спасибо большое за предоставленный синтаксис. Все получилось, но пришлось загрузить 18 демо версию, на 21 день. Теперь понятно, что моя 16 глючная.
Вот результат, который должен сопровождать критерий М-Н. Как раз та самая разница (33,3%), о которой я и раньше писала на форуме и сейчас объясняла Игорю, и ДИ (11,58-50,37).
95%CI for difference in proportions (paired) (*)
Porc. A Porc. B Diferencia Inferior Superior
1 58,33% 25,00% 33,33% 11,58% 50,37%

А в том виде, как Вы привели ничего кроме t-теста не сделать, поскольку данные у Вас в формате, который не дает возможности использовать что бы то ни было другое (можно, правда, рассчитать доверительный интервал разности)
У Вас есть стандартная ошибка и среднее (стандартная ошибка предполагает нормальное распределение). К сожалению, насколько я знаю, SPSS не позволяет считать t-критерий по суммарным данным - в отличие, например, от Stata. Но формулы, состоящие из пары умножений и квадратного корня можно найти в любой книжке (в форуме привести сложно, нет математических знаков). По уму, повторюсь, надо бы было сделать трансформацию процентов, но, так понимаю, исходных данных все равно нет.
Кстати, вопрос к Игорю, а AtteStat по суммарным данным t-критерий и доверительные интервалы считает?

нехорошо, но все же, сходите на avaxhome.ru и введите в поиске portable PASW

Не считает.

У меня где-то есть исходные данные. как подсчитывались проценты.

Чтобы посчитать, эта форула всем известна.

|M1 - M2| / корень квадратный из m1 в квадрате + m2 в квадрате

Если исходные данные по клеткам будут, то тогда какой метод можно использовать?

Не всем. Формула, которую Вы приводите - это для случая неравных дисперсий, там проблема с определением пограничного значения t (в данном случае она явно не годится), нужна формула для равных дисперсий.
Если будут исходные данные по клеткам (т.е., например, число клеток) - то пуассонова регрессия или (если проценты), то см. мой пост выше по смешанным моделям (на самом деле и у тут надо использовать t-тест для связанных совокупностей, но цифры были приведены в таком виде, что...)
Еще более простой вариант - подсчитать разность количества клеток до/после и использовать дисперсионный анализ или просто t-тест для одной выборки.

Уважаемые знатоки, разве можно в таблицах статистических программ достоверность различий по одному столбцу значений рассчитать?
Тоесть скорее всего, это будет однофакторный дисперсионный анализ что ли? Тогда можно рассчитать достоверность по разнице между двумя столбиками значений?
И ещё: готовые результаты средних можно использовать для подсчёта или ?

Можно, одновыборочный t-критерий и его аналоги. ДА требует уже два столбца, как минимум

Два стодбца готовых средних значений или всё же надо добалять в таблицу исходники при однофакторном дисперсионном анализе?

В параметрах однофакторного дисперсионного анализа в одном из параметров диалоговых окон следует выбрать: Что выбирать в константах SPSS. Там указывается "Полином" и в меню "Апостериорные множественные сравнения" куча всяких факторов при равенстве дисперсий и не равенстве дисперсий, какой нужно, а также в разделе параметры указано: статистики описательные и т.д. конкретно для моего случая, если можно?

Если у Вас только два столбца готовых значений, то их можно анализировать напрямую t-тестом или соответствующей непараметриков (соответственно, меню Анализ-Сравнение средних-Одновыборочный t-критерий или Анализ-Непараметрические критерии - для двух связанных выборок)
Если надо пользоваться ДА, то тоже можно оставить все в широком формате (в меню команды искать лень), синтаксис выглядит так:
GLM VAR00001 VAR00002 BY VAR00004
/WSFACTOR = time 2
/WSDESIGN=time
/DESIGN=var00004
/EMMEANS=tables( time*var00004)
/PLOT = profile( time*var00004).

Переменная до, скажем VAR00001, после - VAR00002. Группы, которые сравниваются - в переменной VAR00004.
Синтаксис сам создает фактор повторных изменений по имени time с двумя уровнями. Остальное (таблица средних и график), думаю, понятно.

А то, что вы щелкнули в однофакторном ДА - это контрасты - спланированное заранее сравнение отдельных групп.